获取 Perl 程序中 GET 请求发向的具体 IP

package Web::Checker::Util::HTTP;
use Moo;
use MooX::Types::MooseLike::Base qw/Str Num/;
use AnyEvent::HTTP;
use AnyEvent::Socket;
use AnyEvent;
use Time::HiRes qw/time/;

has peer    => ( is => 'rw', isa => Str );
has reptime => ( is => 'rw', isa => Num );
has clength => ( is => 'rw', isa => Num );
has body    => ( is => 'ro', isa => Str );
has proxy   => ( is => 'ro', isa => Str, default => sub { undef } );
has cv => ( is => 'ro', default => sub { AnyEvent->condvar } );

sub get {
    my ( $self, $url ) = @_;
    $self->cv->begin;
    my $begin = time;
    http_get $url,
      proxy            => $self->proxy,
      # 就是这里发挥了作用，默认应该是直接返回 body 字符串的
      want_body_handle => 1,
      sub {
        my ( $hdl, $headers ) = @_;
        my ( $port, $peer ) =
          AnyEvent::Socket::unpack_sockaddr getpeername $hdl->{fh};
        $self->peer( AnyEvent::Socket::format_address $peer );
        if ( $headers->{Status} =~ /^2/ ) {
            my $end = time;
            $self->reptime( $end - $begin );
            $self->clength( $headers->{'content-length'} );
            $self->cv->end;
        }
      };
    $self->cv->recv;
}

1;