用AnyEvent和ForkManager写一个http协议的压测工具

use Time::HiRes qw/time/;
use AnyEvent::HTTP;
use AnyEvent;
use Coro;

my %code;
my $count = $ARGV[0];
my $url = "https://10.10.10.10/";
my $begin = time;
my @coro = map {
    async {
        my $cv = AnyEvent::condvar;
        $cv->begin;
        my $header_time;
        http_request GET => "$url",
            sub {
                my (undef, $hdr) = @_;
                $code{$hdr->{'Status'}}++;
                $cv->end;
            }
        ;
        $cv->recv;
    }
} (1 .. $count);
$_->join for @coro;
print $cpus*$ARGV[0]/(time-$begin);

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
use Parallel::ForkManager;
use Time::HiRes qw/time/;
use Sys::CpuAffinity;
use AnyEvent::HTTP;
use AE;
use EV;

my $cpus = Sys::CpuAffinity::getNumCpus();
my $pm = new Parallel::ForkManager($cpus, "/tmp/");
my @urls = qw(https://10.11.19.35/ https://10.11.21.121/);
my $res;

$pm->run_on_finish( sub {
    my $data = $_[5];
    $res->{'code'}->{$_} += $data->{'code'}->{$_} for keys %{$data->{'code'}};
    $res->{'size'} += $data->{'size'};
    $res->{'time'} += $data->{'time'};
});

my $begin = time;
foreach my $cpu (1 .. $cpus) {
    my $pid = $pm->start and next;
    Sys::CpuAffinity::setAffinity($$, 2 ** ($cpu-1));
    my $data = ae_get($ARGV[0], \@urls);
    $pm->finish(0, $data);
}
$pm->wait_all_children;
my $use = time - $begin;

printf "%d fetches, %d max processes, in %.03f seconds\n", $ARGV[0] * $cpus, $cpus, $use;
printf "%.03f fetches/sec, %.03f bytes/sec\n", $ARGV[0] * $cpus / $use, $res->{'size'} / $res->{'time'};
printf "HTTP response codes:\n";
printf "       %d - %d\n", $_, $res->{'code'}->{$_} for sort keys %{$res->{'code'}};

sub ae_get {
    my ($count, $urls) = @_;
    my $data;
    my $tmptime;
    my $cv = AE::cv;
    for (1 .. $count) {
        my $hdr_time;
        my $url = $urls->[int(rand($#{$urls}+1))];
        $cv->begin;
        http_request
            GET       => "$url", 
            on_header => sub {
                $hdr_time = time;
            },
            sub {
                my (undef, $hdr) = @_;
                $data->{'code'}->{$hdr->{'Status'}}++;
                $data->{'size'} += $hdr->{'content-length'};
                $data->{'time'} += ( time - $hdr_time );
                $cv->end;
            }
        ;
    } 
    $cv->recv;
    return $data;
}